{
  pkgs,
  config,
  lib,
  ...
}:
let
  gaming-host = lib.mkIf (!config.gaming.client-only);
in
{

  options.gaming.enable = lib.mkEnableOption "Enable steam and related software";
  options.gaming.client-only = lib.mkEnableOption "Only enable steam, to stream via SteamLink";

  config = lib.mkIf config.gaming.enable {
    programs = {
      gamescope = gaming-host {
        enable = true;
        capSysNice = true;
      };

      steam = {
        enable = true;
        gamescopeSession.enable = gaming-host true;

        remotePlay.openFirewall = gaming-host true;
        dedicatedServer.openFirewall = gaming-host true;
        localNetworkGameTransfers.openFirewall = gaming-host true;
      };

      gamemode.enable = gaming-host true;
    };

    hardware.steam-hardware.enable = gaming-host true;

    environment = gaming-host {
      systemPackages = with pkgs; [
        mangohud
        protonup
        protontricks
      ];
    };

    # SteamVR kernel patch for AMDGPU
    boot.kernelPatches = gaming-host [
      {
        name = "amdgpu-ignore-ctx-privileges";
        patch = pkgs.fetchpatch {
          name = "cap_sys_nice_begone.patch";
          url = "https://github.com/Frogging-Family/community-patches/raw/master/linux61-tkg/cap_sys_nice_begone.mypatch";
          hash = "sha256-Y3a0+x2xvHsfLax/uwycdJf3xLxvVfkfDVqjkxNaYEo=";
        };
      }
    ];
  };
}
